目录

简介：

实验任务：

硬件设计：

程序设计：

下载验证：

简介：

呼吸灯采用 PWM 的方式，在固定的频率下，通过调整占空比的方式来控制 LED 灯亮度的变化。PWM即脉冲宽度调制，它利用微处理器输出的 PWM 信号，实现对模拟电路控制的一种非常有效的技术，广泛应用于测量、通信、功率控制等领域。

在由计数器产生的固定周期的 PWM 信号下，如果其占空比为 0，则 LED 灯不亮；如果其占空比为 100%，则 LED 灯最亮。所以将占空比从 0 到 100%，再从 100%到 0 不断变化，就可以实现 LED 灯的“呼吸”效果。

由上图可知，LED 高电平的时间由长渐渐变短，再由短渐渐变长，如果 LED 灯是高电平点亮，则 LED 灯会呈现出亮度由亮到暗，再由暗到亮的过程。

实验任务：

本节实验任务是使用新起点开发板上的 LED，实现呼吸灯的效果，即由灭渐亮，然后再由亮渐灭。

硬件设计：

LED 原理图与―流水灯实验完全相同，请参考―流水灯实验硬件设计部分。

程序设计：

本次实验的模块端口及结构框图如下图所示。

周期信号计数器用于产生驱动 LED 的脉冲信号，本次实验的周期信号频率为 1Khz，其占空比由后级逻辑在每个周期之后进行递增或递减，最后再对当前计数值和占空比计数值进行比较，以输出占空比可调的脉冲信号。

1 module breath_led(
2 input sys_clk , //时钟信号 50Mhz
3 input sys_rst_n , //复位信号
4 
5 output led //LED
6 );
7 
8 //reg define
9 reg [15:0] period_cnt ; //周期计数器频率：1khz 周期:1ms 计数值:1ms/20ns=50000
10 reg [15:0] duty_cycle ; //占空比数值
11 reg inc_dec_flag ; //0 递增 1 递减
12 
13 //*****************************************************
14 //** main code
15 //*****************************************************
16 
17 //根据占空比和计数值之间的大小关系来输出 LED
18 assign led = (period_cnt >= duty_cycle) ? 1'b1 : 1'b0;
19 
20 //周期计数器
21 always @(posedge sys_clk or negedge sys_rst_n) begin
22 if(!sys_rst_n)
23 period_cnt <= 16'd0;
24 else if(period_cnt == 16'd50000)
25 period_cnt <= 16'd0;
26 else
27 period_cnt <= period_cnt + 1'b1;
28 end
29 
30 //在周期计数器的节拍下递增或递减占空比
31 always @(posedge sys_clk or negedge sys_rst_n) begin
32 if(!sys_rst_n) begin
33 duty_cycle <= 16'd0;
34 inc_dec_flag <= 1'b0;
35 end
36 else begin
37 if(period_cnt == 16'd50000) begin //计满 1ms
38 if(inc_dec_flag == 1'b0) begin //占空比递增状态
39 if(duty_cycle == 16'd50000) //如果占空比已递增至最大
40 inc_dec_flag <= 1'b1; //则占空比开始递减
41 else //否则占空比以 25 为单位递增
42 duty_cycle <= duty_cycle + 16'd25;
43 end
44 else begin //占空比递减状态
45 if(duty_cycle == 16'd0) //如果占空比已递减至 0
46 inc_dec_flag <= 1'b0; //则占空比开始递增
47 else //否则占空比以 25 为单位递减
48 duty_cycle <= duty_cycle - 16'd25;
49 end
50 end
51 end
52 end
53 
54 endmodule

第 21-28 行是 1KHz 周期信号的计数器，用于产生 1KHz 的 LED 驱动信号。第 31-52 行的 always 块为占空比设定模块，每次计数完了一个周期，就根据递增/递减标志来对占空比计数值（duty_cycle）进行递增/递减 25 个计数值，这个递增或者递减的数值大小可以用来控制呼吸灯的呼吸频率。如果占空比计数值（duty_cycle）已经递增到了最大，则呼吸灯已经处于最亮的状态，接下来开始递减；如果占空比计数值（duty_cycle）已经递增到了最大，则呼吸灯已经处于最亮的状态，接下来开始递减；往复，最终实现了流水灯的效果。

在代码的第 18 行通过组合逻辑把当前的周期计数值和占空比计数值进行比较，来判断 LED 的输出电平。在一个周期内，如果当前的周期计数值大于等于占空比计数值，则 LED 输出高电平，即点亮；如果当前的周期计数值小于占空比计数值，则 LED 输出低电平，即熄灭。

此代码实际上是通过

assign led = (period_cnt >= duty_cycle) ? 1'b1 : 1'b0;

来实现输出PWM信号的产生，在代码中通过period_cnt与duty_cycle的比较在一段很小的时间内产生对应占空比的方波，通过duty_cycle的不断自动累加/减，来实现整个过程中不同占空比方波的产生

下载验证：

 功能正常